lawnchair/baseline-profile/build.gradle

import com.android.build.api.dsl.ManagedVirtualDevice

plugins {
    alias(libs.plugins.android.test)
    alias(libs.plugins.androidx.baselineprofile)
    alias(libs.plugins.kotlin.android)
}

android {
    namespace 'app.lawnchair.baseline'

    defaultConfig {
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    targetProjectPath = ":"

    flavorDimensions += ["app", "recents", "channel"]
    productFlavors {
        lawn { dimension = "app" }
        withQuickstep { dimension = "recents" }
        github { dimension = "channel" }
        market { dimension = "channel" }
    }

    testOptions.managedDevices.devices {
        pixel6Api33(ManagedVirtualDevice) {
            device = "Pixel 6"
            apiLevel = 33
            systemImageSource = "google"
        }
    }
}

// This is the configuration block for the Baseline Profile plugin.
// You can specify to run the generators on a managed devices or connected devices.
baselineProfile {
    managedDevices += "pixel6Api33"
    useConnectedDevices = false
}

dependencies {
    implementation libs.androidx.junit
    implementation libs.androidx.espresso.core
    implementation libs.androidx.uiautomator
    implementation libs.androidx.benchmark.macro.junit4
}